1 files changed, 69 insertions, 0 deletions
diff --git a/x11-terms/st-sx/st-sx-9999.ebuild b/x11-terms/st-sx/st-sx-9999.ebuild
new file mode 100644
index 0000000..6aabf6b
--- /dev/null
+++ b/x11-terms/st-sx/st-sx-9999.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit git-r3 desktop toolchain-funcs
+
+DESCRIPTION="Simple terminal implementation for X"
+HOMEPAGE="https://st.suckless.org/"
+EGIT_REPO_URI="https://github.com/veltza/st-sx"
+
+PATCHES=(
+	${FILESDIR}/config.diff
+)
+
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	>=sys-libs/ncurses-6.0:0=
+	media-libs/fontconfig
+	media-libs/gd
+	x11-libs/libX11
+	x11-libs/libXft
+	x11-terms/st-terminfo
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
+		-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
+		-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
+		config.mk || die
+	sed -i \
+		-e '/tic/d' \
+		Makefile || die
+}
+
+src_configure() {
+	sed -i \
+		-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
+		config.mk || die
+
+	tc-export CC
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+
+	dodoc TODO
+
+	make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "Please ensure a usable font is installed, like"
+		elog "    media-fonts/corefonts"
+		elog "    media-fonts/dejavu"
+		elog "    media-fonts/urw-fonts"
+	fi
+}